- 自動化ツールUWSC使いよ集まれ21
434 ：名無しさん＠お腹いっぱい。[sage]：2018/10/15(月) 02:38:56.81 ID:xoZP11HR0 - // くちばし先端を指定した場合くちばし先端をx,yに合わせるBALOON
// x,yに合わせることでBALOONがデスクトップ外に出てしまう場合などは考慮していない
PROCEDURE BALOON_EX(str="", x=0, y=0, direction=0, fontsize=0, fontname="", color_fg=1, color_bg=0, transparent=0)
IF 0<direction AND 5>direction THEN
balloon(str, -1000, -1000, direction, fontsize, fontname, color_fg, color_bg, transparent)
MOVE_BALOON(x, y , direction)
ELSE
balloon(str, x, y, direction, fontsize, fontname, color_fg, color_bg, transparent)
ENDIF
FEND
// BALOONのくちばし先端をx,y位置に移動する
// direction 1：上嘴(yの下へ), 2：下嘴(yの上へ), 3：左嘴(xの右へ), 4：右嘴(xの左へ)
// SAVEIMG()でクリップボードにおいたイメージをPEEKCOLOR()で見ているので注意
FUNCTION MOVE_BALOON(x, y, direction)
| - 自動化ツールUWSC使いよ集まれ21
435 ：名無しさん＠お腹いっぱい。[sage]：2018/10/15(月) 02:39:30.50 ID:xoZP11HR0 - FUNCTION MOVE_BALOON(x, y, direction)
RESULT=FALSE
DIM idBaloon = GETID(GET_BALLOON_WIN)
IFB -1 < idBaloon THEN
DIM xBaloon = STATUS( idBaloon, ST_CLX ); DIM yBaloon = STATUS( idBaloon, ST_CLY )
DIM wBaloon = STATUS( idBaloon, ST_CLWIDTH );DIM hBaloon = STATUS( idBaloon, ST_CLHEIGHT )
DIM widthTrim = -1
IFB 1=direction THEN
SAVEIMG("", idBaloon, 0, 1, wBaloon, 1, TRUE )
ELSEIF 2=direction THEN
SAVEIMG("", idBaloon, 0, hBaloon-1, wBaloon, 1, TRUE )
ENDIF
IFB 1=direction OR 2=direction THEN
DIM xSearch = 0
WHILE (xSearch<wBaloon)
IFB 0 = PEEKCOLOR( xSearch, 0, 0, TRUE) THEN
widthTrim = xSearch; BREAK
ENDIF
xSearch = xSearch + 1
WEND
ENDIF
IFB 1=direction THEN
RESULT=TRUE; ACW( idBaloon, x-(widthTrim), y)
ELSEIF 2=direction THEN
RESULT=TRUE; ACW( idBaloon, x-(widthTrim), y-hBaloon)
ELSEIF 3=direction THEN
RESULT=TRUE; ACW( idBaloon, x, y-(hBaloon/3))
ELSEIF 4=direction THEN
RESULT=TRUE; ACW( idBaloon, x-wBaloon, y-(hBaloon/3))
ENDIF
ENDIF
FEND
| - 自動化ツールUWSC使いよ集まれ21
436 ：名無しさん＠お腹いっぱい。[sage]：2018/10/15(月) 02:41:55.12 ID:xoZP11HR0 - 使用サンプル
BALOON_EX("1", G_MOUSE_X,G_MOUSE_Y, 1, 0, "System",$1,$d0FFFF)
msgbox("下につけた")
BALOON_EX("あ", G_MOUSE_X,G_MOUSE_Y, 2, 49, "ＭＳ ゴシック",$1,$d0FFFF)
msgbox("上につけた")
BALOON_EX("cursor", G_MOUSE_X,G_MOUSE_Y,3, 36, "Times New Roman",$1,$d0FFFF)
msgbox("右につけた")
BALOON_EX("カーソル", G_MOUSE_X,G_MOUSE_Y, 2, 24, "ＭＳ ゴシック",$1,$d0FFFF)
msgbox("上につけた")
print "TEST Target Window"
DIM idwndTarget = GETID(GET_LOGPRINT_WIN)
DIM ileftTarget = STATUS( idwndTarget, ST_CLX )
DIM itopTarget = STATUS( idwndTarget, ST_CLY )
DIM irightTarget = ileftTarget + STATUS( idwndTarget, ST_CLWIDTH )
DIM ibottomTarget = itopTarget + STATUS( idwndTarget, ST_CLHEIGHT )
BALOON_EX("12あかさたな12345678901234567890<#CR>はまやらわ<#CR>12345678901234567890", ileftTarget,ibottomTarget, 1, 49, "ＭＳ ゴシック",$1,$d0FFFF)
msgbox("下につけた")
BALOON_EX("あかさたな12345678901234567890<#CR>はまやらわ<#CR>12345678901234567890", ileftTarget,itopTarget, 2, 24, "ＭＳ Ｐ明朝",$1,$d0FFFF)
msgbox("上につけた")
BALOON_EX("あかさたな1234567890<#CR>はまやらわ<#CR>1234567890<#CR>12345678901234567890<#CR>12345678901234567890<#CR>12345678901234567890", irightTarget,itopTarget, 3, 18, "ＭＳ ゴシック",$1,$d0FFFF)
msgbox("右につけた")
BALOON_EX("あかさたな1234567890<#CR>はまやらわ<#CR>1234567890<#CR>12345678901234567890<#CR>12345678901234567890<#CR>12345678901234567890", ileftTarget,itopTarget, 4, 9, "ＭＳ ゴシック",$1,$d0FFFF)
msgbox("左につけた")
BALOON_EX()
msgbox("消した")
BALOON_EX("てすと")
msgbox("デフォルト")
| - 自動化ツールUWSC使いよ集まれ21
437 ：名無しさん＠お腹いっぱい。[sage]：2018/10/15(月) 02:49:44.79 ID:xoZP11HR0 - >>434
×// くちばし先端を指定した場合くちばし先端をx,yに合わせるBALOON
○// 向きにくちばし(1〜4)を指定した場合くちばし先端をx,yに合わせるBALOON
// 引数はすべて BALLOON()/FUKIDASI()と同じ
|
|